Excel: cosa è in grado di fare MATR.SOMMA.PRODOTTO? Ecco la funzione spiegata in breve!

Certo, il nome è un po' fuorviante. La funzione non dà, come si potrebbe facilmente pensare, il prodotto (cioè il risultato di una moltiplicazione) di diverse somme (risultato di un'addizione). È anzi proprio il contrario: vengono sommati diversi prodotti per ottenere un totale. In Excel, MATR.SOMMA.PRODOTTO è utile sia con tabelle piccole che con matrici grandi.

Per cosa è utile la funzione MATR.SOMMA.PRODOTTO?

La funzione MATR.SOMMA.PRODOTTO può essere utile ogni volta che moltiplicate più valori in Excel e poi volete sommare i risultati ottenuti. Ad esempio, se nel foglio di lavoro sono presenti più matrici e volete effettuare un calcolo con esse, con MATR.SOMMA.PRODOTTO è molto semplice. Cominciamo con una tabella a due colonne: con MATR.SOMMA.PRODOTTO potete moltiplicare i due valori di ciascuna riga e sommare tutti i risultati.

MATR.SOMMA.PRODOTTO è una formula di matrice. Quando volete utilizzare una funzione come formula di matrice, la formula immessa viene generalmente confermata con la combinazione di tasti [Ctrl] + [Maiusc] + [Invio]. Con MATR.SOMMA.PRODOTTO non è necessario. La funzione di per sé è già preposta all'elaborazione di matrici. Excel non ha quindi bisogno di alcun segnale speciale.

Sintassi di MATR.SOMMA.PRODOTTO di Excel

La funzione di Excel MATR.SOMMA.PRODOTTO ha un struttura relativamente semplice. Di solito vanno specificate solo le aree che devono essere incluse nel calcolo.

=MATR.SOMMA.PRODOTTO(Matrix1;[Matrix2];[array3]...)

Nella formula deve quindi essere nominata almeno una matrice. Tuttavia, è possibile inserire fino a 256 voci. Excel offre diverse possibilità per compilare il parametro. È possibile immettere la matrice mediante riferimento di cella, fare riferimento all'area desiderata con un nome o immettere direttamente un array (ovvero una raccolta di valori) nella formula.

  • Area di celle: =MATR.SOMMA.PRODOTTO(A2:A6;B2:B6)
  • Nome: =MATR.SOMMA.PRODOTTO(matrice1;matrice2)
  • Array: =MATR.SOMMA.PRODOTTO({15;27;12;16;22};{2;5;1;2;3})
N.B.

Per utilizzare i nomi all'interno della funzione, è necessario innanzitutto definirli. A tale scopo, selezionate l'area corrispondente includendo un'intestazione in cui avrete già inserito il nome, quindi andate su “Formule” e “Crea da selezione”.

Le aree di celle corrispondenti devono essere sempre simmetriche: se ad esempio la seconda matrice contiene una riga o un valore in meno rispetto alla prima area, verrà visualizzato un messaggio di errore.

Funzione MATR.SOMMA.PRODOTTO nella pratica

La funzione MATR.SOMMA.PRODOTTO comporta alcuni vantaggi: quello più ovvio è che, combinando moltiplicazione e addizione, si risparmiano diversi passaggi di calcolo. In più, MATR.SOMMA.PRODOTTO si combina molto bene con altre funzioni. La funzione consente anche trucchi interessanti per attività più complesse.

MATR.SOMMA.PRODOTTO con confronto

Ad esempio, MATR.SOMMA.PRODOTTO ha un elemento integrato simile alla funzione SOMMA.SE. Esso consente di selezionare quali valori all'interno delle matrici devono essere inclusi nel calcolo. A tale scopo, basta modificare la sintassi effettiva della funzione:

=MATR.SOMMA.PRODOTTO((A2:A11=A14)*B2:B11*C2:C11)

Nel primo argomento abbiamo inserito un confronto. Solo se i dati corrispondono al valore nella cella A14, le celle corrispondenti vengono moltiplicate e poi sommate. Oltre al segno uguale che esegue il confronto, sono stati aggiunti segni di moltiplicazione. Nella sintassi normale, le aree possono essere separate facilmente con un punto e virgola. Excel di solito capisce come gestire le informazioni. Tuttavia, se si include il confronto, la funzione richiede una chiara distinzione dell'operazione aritmetica, altrimenti ci sarà un errore.

Altre possibilità di moltiplicazione

È possibile utilizzare l'asterisco per eseguire la moltiplicazione in modo diverso. Come accennato in precedenza, la funzione funziona solo se le aree specificate hanno lo stesso numero di celle. Tuttavia, può essere che vogliate moltiplicare sempre per lo stesso valore. Teoricamente, per farlo dovreste usare una matrice in cui in ogni cella appare lo stesso valore. Invece, è possibile inserire il valore solo una volta in una cella e utilizzare la notazione con “*”.

=MATR.SOMMA.PRODOTTO(A1:A10*$B$1)

Come altro esempio, supponiamo che vogliate sommare diverse celle e quindi moltiplicarle per un valore e infine sommare i risultati. Esistono due modi per farlo con Excel:

=MATR.SOMMA.PRODOTTO(A2:C6*D2:D6)

Ancora una volta utilizziamo il segno per. I valori nella grande area vengono prima sommati e poi moltiplicati per la seconda area.

=MATR.SOMMA.PRODOTTO((A2:A6+B2:B6+C2:C6);D2:D6)

In questa formula è quindi possibile utilizzare nuovamente il punto e virgola. Per farlo, però, bisogna dire esplicitamente a Excel che le singole aree devono essere prima sommate.

Combinare MATR.SOMMA.PRODOTTO con altre funzioni

La funzione MATR.SOMMA.PRODOTTO può naturalmente essere combinata anche con altre funzioni di Excel. È quindi possibile eseguire più passaggi in una formula e non è necessario lavorare con celle ausiliarie per ottenere risultati intermedi. Ad esempio, potete ottenere il risultato della funzione direttamente arrotondato:

=ARROTONDA.PER.DIF(MATR.SOMMA.PRODOTTO(A2:A6;B2:B6);-1)

In questo esempio MATR.SOMMA.PRODOTTO è integrata nella funzione ARROTONDA.PER.DIF e funge da primo parametro.

In sintesi

In Excel MATR.SOMMA.PRODOTTO offre molte possibilità per semplificare i calcoli complessi. La funzione può essere utilizzata sia da sola che in combinazione con altre funzioni.


Insieme ce la faremo. Noi di IONOS
#siamoquiperte
L'emergenza coronavirus è una sfida che dobbiamo vincere insieme.
In questo momento di incertezza vogliamo aiutarti a mandare
avanti la tua attività.
3 mesi omaggio
E-commerce
Crea il tuo negozio online.