La funzione Excel CONTA.SE: a cosa serve?

Molteplici utilissime funzioni di Excel rimangono purtroppo oscure a chi lo utilizza soltanto per creare tabelle a mano. Tuttavia questa applicazione può alleggerire il vostro carico di lavoro sia nella vita privata che in ambito professionale. Per poter approfittare appieno dei vantaggi delle tabelle di calcolo occorre innanzitutto comprendere le funzioni, tra cui rientra anche la menzionata CONTA.SE (in inglese COUNTIF). In questo articolo spieghiamo a cosa serve questa funzione e come utilizzarla correttamente.

A cosa serve CONTA.SE?

Immaginate di avere una lista di voci non ordinate, dove ad esempio sono elencate le vendite dell’ultimo mese. Ora volete scoprire con quale frequenza è stato venduto un determinato prodotto. Anziché dover scandagliare a mano l’intera lista, in questo caso potete usare la funzione CONTA.SE, che conta la cella soltanto se all’interno è contenuto il valore richiesto.

In Excel la funzione CONTA.SE è una funzione statistica, come si può riconoscere già dall’esempio utilizzato. Se vi ponete la stessa domanda “Quanto spesso è stato venduto l’articolo X” per ogni articolo disponibile, scoprirete ad esempio facilmente quale tra i prodotti è il più amato. Con i dati statistici si possono creare anche grafici.

Nella funzione CONTA.SE si tratta di una combinazione della funzione SE (che è una funzione logica) e di quella CONTA.NUMERI, per la precisione CONTA.VALORI (che è invece una funzione statistica). Con questa combinazione perciò una cella viene contata soltanto se soddisfa un determinato valore.

Non bisogna confondere la funzione CONTA.SE con quella SOMMA.SE: mentre la prima conta il numero di voci che contengono il valore, la seconda funzione somma i valori contenuti nelle celle corrispondenti. Con SOMMA.SE, per intenderci, si capisce quanti singoli prodotti di quel tipo sono stati venduti.

Come funziona? CONTA.SE all’opera

Nelle funzioni Excel è importante attenersi alla sintassi corretta:

=CONTA.SE(intervallo;criterio di ricerca)

Con il concetto di intervallo si intendono le celle della tabella nelle quali ci sono i valori da contare. Il criterio di ricerca stabilisce il valore a cui si è interessati. L’intervallo deve essere comunicato con un punto di inizio e uno di fine, tra i quali ci devono essere i due punti. Ad esempio se si inserisce “B3:B14” si indica di considerare, oltre alla cella B3 e alla cella B14, tutte le celle tra esse comprese.

In alternativa Excel vi dà la possibilità di trascinare gli intervalli con il mouse, potendo visualizzare immediatamente i risultati grazie alla marcatura colorata che le celle assumono man mano che si trascina il cursore. Si può anche selezionare una colonna completa: per farlo bisogna dare come valore soltanto la colonna senza numeri: “B:B”. Funziona naturalmente allo stesso modo con le righe.

Potete indicare il criterio di ricerca sia come valore, da inserire tra virgolette (ad esempio “scarpe”) sia selezionando una cella nella quale è presente il valore richiesto (ad esempio B3). L’intervallo e il criterio di ricerca sono separati da un punto e virgola. Inoltre nella sintassi non devono esserci spazi.

=CONTA.SE(B3:B14;"scarpe")

=CONTA.SE(B3:B14;F3)

N.B.

Le funzioni in Excel devono sempre essere introdotte dal segno di uguale, altrimenti il programma interpreta il dato inserito come una semplice sequenza di caratteri e lo inserisce semplicemente nella cella corrispondente.

Excel offre anche la possibilità del completamento automatico. Basta trascinare la funzione cliccando sul puntino che compare in basso a destra della cella selezionata: trascinando quel puntino in basso e la funzione verrà applicata anche alle righe successive. Le celle specificate nell’intervallo e i criteri di ricerca si regoleranno automaticamente. Se invece non volete cambiare l’intervallo considerato, potete inserirlo come valore assoluto, inserendo il segno del dollaro:

=CONTA.SE($B$3:$B$14;F3)

CONTA.SE ha anche una funzione ampliata di nome CONTA.PIÙ.SE, con la quale potete inserire più intervalli e più criteri di ricerca nella vostra funzione. Per esempio potete ora contare soltanto quelle vendite di scarpe che contengono più di un prodotto:

=CONTA.PIÙ.SE(B3:B14;$G4;C3:C14;>1)

N.B.

La funzione CONTA.SE non tiene conto delle lettere maiuscole o minuscole.

La funzione CONTA.SE chiarita con esempi

Poniamo che voi possediate un negozio e vogliate scoprire quanti acquirenti vengono dalla vostra zona. Per farlo avete chiesto a tutti loro se fossero disposti a comunicarvi il loro codice di avviamento postale. Avete quindi inserito tutti i dati uno dopo l’altro in una tabella. Ora per esempio potete contare le celle nelle quali si trova il vostro stesso codice di avviamento postale.

=CONTA.SE(B3:B17;"10969")

Consiglio

In questo esempio utilizziamo i numeri come testo. Per la funzione CONTA.SE di principio non fa alcuna differenza, ma per non avere problemi in altre situazioni, dovreste formattare anche le celle come testo.

In questo modo scoprite quanti clienti vengono dalla vostra zona. Se ora volete scoprire il contrario, ossia chi ha un codice di avviamento postale diverso dal vostro, dovete inserire prima del criterio di ricerca un “minore” (<) e un “maggiore” (>).

=CONTA.SE(B3:B17;"<>10969")

Se desiderate riferirvi al valore di una particolare cella anziché inserire direttamente il valore nella funzione, potete unire la negazione (“<>”) alla cella utilizzando l’operatore di concatenazione (&):

=CONTA.SE(B3:B17;"<>"&B3)

Inoltre ammettiamo che abbiate chiesto ai clienti anche l’età e che abbiate assegnato questi numeri al corrispettivo codice di avviamento postale in una colonna. Partendo dal presupposto che la vostra offerta sia per lo più rivolta a persone sopra i 50 anni, vorreste verificare questa vostra assunzione: un caso perfetto per utilizzare la funzione CONTA.SE. Poiché volete contare non soltanto i clienti sopra i 50, ma anche quelli che hanno 50 anni esatti, la funzione deve contenere il “maggiore” e l’“uguale”:

=CONTA.SE(C3:C17;">=50")

In questo caso sarete ovviamente interessati anche ai risultati negativi, ovvero quante sono le persone sotto i 50 anni. Per farlo non avete bisogno di alcuna negazione, dato che il simbolo “minore” è sufficiente

=CONTA.SE(C3:C17;"<50")

Se qualcuno non ha fornito indicazioni sull’età, questo valore semplicemente non viene contato. Potete constatare che la semplice rimozione di un codice di avviamento postale che non è 10969 non ha alcun effetto sul risultato. Da qui potete ampliare la vostra formula contando tutte le celle aggiuntive che sono vuote e sottrarre il loro numero dal primo risultato. Per dire ad Excel che volete utilizzare le celle vuote come criterio di ricerca, lasciate la parte tra le virgolette vuota (in pratica dovete scrivere le virgolette di apertura e chiusura semplicemente una accanto all’altra):

=CONTA.SE(B3:B17;"<>10969")-CONTA.SE(B3:B17;"")

In alternativa potete usare in questo caso la funzione ampliata CONTA.PIÙ.SE. Come utilizzarla? Basta inserire nella vostra formula originaria un ulteriore criterio di ricerca, per la precisione che le celle vuote non debbano essere contate. In questo modo non dovete sottrarre tutte le celle vuote, ma semplicemente verranno in partenza escluse dal conteggio:

=CONTA.PIÙ.SE(B3:B17;"<>10969";B3:B17;"<>")

Se ora per qualche motivo voleste scoprire quanti tra i clienti dai 50 anni in su abbiano il vostro stesso codice di avviamento postale, potete utilizzare ancora la funzione CONTA.PIÙ.SE, inserendo un ulteriore criterio nella formula:

=CONTA.PIÙ.SE(B3:B17;”10969”;B3:B17;"<>";C3:C17;">=50")

N.B.

Excel presenta dei problemi con la funzione CONTA.SE nel caso di stringhe lunghe. Se volete utilizzare criteri di ricerca con più di 255 caratteri potete concatenare più criteri tra di loro utilizzando l’operatore di concatenazione “&”: =CONTA.SE(B3:B17;"109"&"69").

Nel vostro sondaggio avete inoltre preso nota di cosa i clienti abbiano comprato di volta in volta. Come proprietario di un negozio di scarpe volete sapere con quale frequenza sono state vendute alcune scarpe e volete tenere conto soltanto delle vendite che riguardano questo articolo. Per farlo potete inserire un carattere jolly, in questo caso l’asterisco (*).

Ponendo l’asterisco dopo la parola “scarpe”, verranno conteggiate soltanto quelle celle dove la parola scarpa è seguita da altre parole, mentre inserendo l’asterisco prima della parola “scarpe”, otterrete tutti i risultati che hanno altre parole prima di “scarpe”. Nel nostro caso, per considerare soltanto le voci che riguardano le scarpe vere e proprie (e non lacci per scarpe etc), dobbiamo mettere l’asterisco dopo la parola scarpe:

=CONTA.SE(D3:D17;"scarpe*")

N.B.

I caratteri jolly funzionano soltanto quando si tratta di inserire testo. I valori numerici non si possono sostituire. Lo stesso vale per il punto di domanda (?) come metacarattere, con il quale potete sostituire un carattere. Se invece state cercando esattamente un punto di domanda o un asterisco, occorre inserire prima una tilde (~).