Excel: risolvere gli intoppi con SE.ERRORE

Il principio Se-Allora-Altrimenti di Excel è molto utilizzato per costruire formule. Un’azione deve essere eseguita solo se si verifica una data condizione. Generalmente, tale condizione fa riferimento a determinati valori o stringhe. Tuttavia, è abbastanza frequente che Excel generi un messaggio di error all’interno di una cella. Questo può essere dovuto al fatto che la formula non è stata scritta correttamente o che non contiene tutti i valori necessari per eseguire un calcolo corretto. In questi casi, la funzione SE.ERRORE vi permette di creare un’alternativa accettabile.

A che cosa serve la funzione SE.ERRORE in Excel?

Ogni qualvolta Excel non riesce ad eseguire correttamente un calcolo o un’azione, il programma genera un messaggio di errore direttamente nella cella. Il messaggio si riconosce generalmente per il fatto che inizia con il simbolo cancelletto (#).

  • #ND: la formula non riesce a trovare ciò che si cerca.
  • #VALORE!: un argomento è di tipo sbagliato.
  • #RIF!: una formula rimanda a una cella non valida.
  • #DIV/0!: viene generato quando si tenta di dividere per una cella vuota o che ha il valore ZERO.
  • #NUM!: la formula si aspetta un valore numerico, ma trova qualcos’altro.
  • #NOME?: viene generato perlopiù quando il nome della funzione contiene un errore di battitura.
  • #NULLO!: viene generato in caso di assegnazione di intersezioni inesistenti.

Nella maggior parte dei casi, l’utente reagisce a questi errori tentando di risolvere il problema che li ha causati. Può tuttavia anche accadere che questi errori siano stati previsti e non si desideri risolverli direttamente. In questo caso è utile utilizzare la funzione SE.ERRORE. Questa vi offre ad esempio la possibilità di sostituire la visualizzazione dell’errore con un messaggio o un valore da voi stessi definito.

In questo modo, non solo il foglio di lavoro risulta più ordinato, ma si evita anche di influenzare gli altri calcoli. Se in un’altra formula avete definito un intervallo di celle in cui viene generato un messaggio di errore, può accadere che anche questa formula generi a propria volta un errore. Per ovviare a una situazione di questo tipo, con la funzione SE.ERRORE è possibile immettere un valore con cui la formula può lavorare.

Fatto

Excel conosce anche la funzione VAL.ERRORE. Questa genera i valori VERO o FALSO a seconda che venga o meno rilevato un errore. La maggior parte degli utenti ricorre tuttavia a una funzione SE. La funzione SE.ERRORE permette di risparmiare la necessità di un annidamento.

Sintassi della funzione SE.ERRORE

Con la funzione SE.ERRORE, Excel semplifica di molto la vita degli utenti. La funzione richiede di inserire soltanto due argomenti: Dove può verificarsi un errore? Cosa deve accadere se viene rilevato un errore?

=SE.ERRORE(valore; se_errore)

Cosa occorre specificare nei due argomenti?

  • Valore: qui viene specificato cosa deve essere controllato per rilevare la presenza di un errore. Potete immettere direttamente un calcolo o un’altra funzione, oppure creare un rimando a una cella.
  • Se_errore: in questo argomento viene specificato cosa deve accadere in caso di errore. È possibile immettere valori numerici, stringhe o anche altre funzioni. Se si desidera che venga visualizzato un testo, questo deve essere racchiuso tra virgolette doppie.
N.B.

In Excel, le formule iniziano sempre con un simbolo di uguale (=). Se si dimentica di inserire il simbolo, la formula viene visualizzata nella cella come testo semplice. Se, invece, è proprio questo che volete, e desiderate anche che il simbolo di uguale venga visualizzato all’interno della cella, fate precedere alla formula una virgoletta semplice (’).

Spiegazione di SE.ERRORE con esempi

Questa funzione Excel può essere utilizzata nelle più svariate situazioni, da sola o in combinazione con altre funzioni.

Visualizzazione alternativa con SE.ERRORE

Il modo forse più semplice di implementare SE.ERRORE nel lavoro in Excel è quello di modificare la visualizzazione dell’errore. Per comprendere questo concetto utilizziamo un semplice calcolo: il valore nella cella A3 viene moltiplicato con il valore nella cella B3. Se, in uno dei due riferimenti, viene immessa una lettera anziché un numero (ad esempio a causa di un errore di battitura), Excel visualizza il messaggio di errore #VALORE!. Tuttavia, collegando il calcolo alla funzione SE.ERRORE, è possibile modificare questa visualizzazione.

=SE.ERRORE(A3*B3; "Valori errati")
Consiglio

Se desiderate che, in caso di errore, la cella rimanga vuota, immettete due virgolette di seguito.

Così facendo viene visualizzato il risultato corretto oppure il messaggio di errore definito dall’utente. Se sono presenti più calcoli di questo tipo, applicate la formula a tutte le righe.

Anziché sostituire il messaggio di errore direttamente, potete applicare SE.ERRORE anche su un’altra cella e, in questo modo, creare un commento.

=SE.ERRORE(C3; "Qui c’è un errore")

In questo caso, se non è presente alcun errore, la funzione mostra tuttavia nuovamente lo stesso valore di C2. Questo perché la funzione SE.ERRORE non conosce nessun valore Altrimenti. Per ovviare a questo inconveniente, l’alternativa migliore è combinare la funzione SE alla funzione VAL.ERRORE:

=SE(VAL.ERRORE(C2)=VERO; "Qui c’è un errore"; "")

SE.ERRORE & CERCA.VERT: soluzione alternativa a #ND

Nell’utilizzo pratico di Excel, la funzione SE.ERRORE si rivela particolarmente utile in combinazione con la funzione CERCA.VERT. Quest’ultima, nello specifico, genera notoriamente l’errore #ND. CERCA.VERT permette di implementare una funzione di ricerca direttamente nel foglio di lavoro Excel. Tuttavia, se la formula contiene un errore o se il termine cercato viene digitato in modo errato, Excel genera un messaggio di errore. Con SE.ERRORE potete sostituire il messaggio di errore #NV, di per sé poco utile, con un messaggio di vostra scelta.

=SE.ERRORE(CERCA.VERT("Lung, Fritz";A2:C7;2;0); "Dato errato")

La ricerca di “Lung, Fritz” genererebbe di fatto l’errore #ND, in quanto il nome cercato non corrisponde esattamente al nome inserito in tabella (poiché l’ultimo argomento in CERCA.VERT è impostato su 0, non sono ammessi valori di approssimazione). Tuttavia, inserendo nella formula la funzione nidificata SE.ERRORE, anziché #ND viene visualizzato il messaggio di errore da voi scelto.

La funzione di Excel SE.ERRORE è utile anche quando più CERCA.VERT vengono concatenate. Supponiamo che vogliate cercare un oggetto all’interno di una tabella. Se nella tabella l’oggetto non viene trovato, deve essere cercato nella tabella successiva, e così di seguito. Poiché CERCA.VERT genera un errore se la voce cercata non viene trovata, con SE.ERRORE è possibile avviare una nuova funzione CERCA.VERT.

=SE.ERRORE(CERCA.VERT(100;A3:B7;2;0); SE.ERRORE(CERCA.VERT(100;D3:E7;2;0); SE.ERRORE(CERCA.VERT(100;G3:H7;2;0); "Non trovato")))

Ogni volta che CERCA.VERT non trova l’argomento cercato e genera quindi un errore, la funzione passa alla tabella successiva. Se il valore cercato non è presente nemmeno nell’ultima tabella, viene visualizzato un messaggio impostato dall’utente.

Consiglio

Excel conosce anche la funzione SE.NON.DISP. Questa lavora in modo analogo a SE.ERRORE, tuttavia è limitata al messaggio di errore #ND. Utilizzando questa funzione anziché la funzione più ampia SE.ERRORE, vengono filtrati solo gli errori #ND. Tutti gli altri errori continuano ad essere visualizzati. Questo vi permette di reagire in modo più efficace agli errori nella vostra formula.

SE.ERRORE & SOMMA: sostituzione dell’errore con un valore

Supponiamo che abbiate diversi calcoli e che vogliate sommare i risultati con la funzione SOMMA. Nel caso in cui uno dei calcoli contenga un errore ed Excel, anziché un valore numerico, visualizzi un messaggio di errore, anche la funzione di sommatoria non può funzionare correttamente. È quindi consigliabile verificare i calcoli immessi con la funzione SE.ERRORE e, anziché il messaggio di errore, visualizzare semplicemente il valore 0. Questo fa sì, da una parte, che la funzione possa eseguire il suo compito e, dall’altra, che la somma non venga falsata.

=SE.ERRORE(A3*B3; 0)

Avete anche la possibilità di impostare un testo alternativo solo per la funzione SOMMA, così da segnalare all’utente la presenza di un errore.

=SE.ERRORE(SOMMA(C2:C7); "Valori errati")
In sintesi

Con la funzione SE.ERRORE potete sostituire nelle più svariate situazioni i messaggi di errore di Excel con messaggi o valori da voi impostati. È tuttavia anche possibile utilizzare SE.ERRORE in modo da ottenere formule più complesse.

Per offrirti una migliore esperienza di navigazione online questo sito web usa dei cookie, propri e di terze parti. Continuando a navigare sul sito acconsenti all’utilizzo dei cookie. Scopri di più sull’uso dei cookie e sulla possibilità di modificarne le impostazioni o negare il consenso.
Page top